*-----------------------------------------------------------
* Title      : testmem
* Written by : rzh
* Date       : February 2014
* Description: test SRAM memory
*-----------------------------------------------------------
       org     $100000

astat  equ     $700000
actrl  equ     $700000
ainp   equ     $700002
aout   equ     $700002

leds   equ     $700020

btram  equ     0
tpram  equ     $100000

cr     equ     $d
lf     equ     $a

start:
       dc.l    $A0000
       dc.l    init

init:  move.b  #3,actrl
       move    #$400,d0
dlay:  subq    #1,d0
       bne     dlay
       move.b  #$15,actrl

       move.b  #$41,d5

blink: move.l  #$F,d2
blp:   move.l  #$AAAA,d0
       move.w  d0,leds
       move.l  #$FFFF,d1
       dbf     d1,*
       move.l  #$5555,d0
       move.w  d0,leds
       move.l  #$FFFF,d1
       dbf     d1,*
       dbf     d2,blp

       movea.l #btram,a4
lp1    move.b  #$AA,(a4)+
       cmpa.l  #tpram,a4
       bne.s   lp1

       movea.l #btram,a4
lp2    cmpi.b  #$AA,(a4)+
       bne     fail
       cmpa.l  #tpram,a4
       bne.s   lp2

       lea.l   pmsg,a5
       bra.s   prt
fail:  lea.l   fmsg,a5
prt    move.b  (a5)+,d0
olp    btst    #1,astat
       beq     olp
       move.b  d0,aout
       cmpi.b  #0,(a5)
       bne     prt

       move.w  d5,-(sp)
ck1lp  btst    #1,astat
       beq     ck1lp
       move.w  (sp)+,d0
       move.b  d0,aout
ck2lp  btst    #1,astat
       beq     ck2lp
       move.b  d5,aout
       addq    #1,d5

       bra     blink

pmsg:  dc.b   cr,lf,'passed',0
fmsg:  dc.b   cr,lf,'failed',0

       end    start